//=============================================================================
// UPakRocket.uc
// $Author: Deb $
// $Date: 4/23/99 12:14p $
// $Revision: 1 $
//=============================================================================
class FsRocket expands Projectile;

#exec mesh IMPORT MESH=rocketL ANIVFILE=MODELS\ROCKETLAUNCHER\rocketL_a.3d DATAFILE=MODELS\ROCKETLAUNCHER\rocketL_d.3d X=0 Y=0 Z=0
#exec MESH ORIGIN MESH=rocketL X=20 Y=0 Z=-2

#exec mesh SEQUENCE MESH=rocketL SEQ=All   STARTFRAME=0 NUMFRAMES=5
#exec MESH SEQUENCE MESH=rocketL SEQ=PopUp STARTFRAME=0 NUMFRAMES=1
#exec MESH SEQUENCE MESH=rocketL SEQ=Wings STARTFRAME=1 NUMFRAMES=1
#exec MESH SEQUENCE MESH=rocketL SEQ=Fly   STARTFRAME=2 NUMFRAMES=3

#exec texture IMPORT NAME=JrocketL1 FILE=MODELS\ROCKETLAUNCHER\rocketL1.PCX GROUP=Skins LODSET=2 // rocket01

#exec MESHMAP NEW   MESHMAP=rocketL MESH=rocketL
#exec MESHMAP SCALE MESHMAP=rocketL X=0.375 Y=0.375 Z=0.75

#exec MESHMAP SETTEXTURE MESHMAP=rocketL NUM=1 TEXTURE=JrocketL1

#exec AUDIO IMPORT FILE="Sounds\RocketLauncher\RocketLoop2.WAV" NAME="RocketLoop2" GROUP="RocketLauncher"
#exec AUDIO IMPORT FILE="Sounds\RocketLauncher\RocketLoop1.WAV" NAME="RocketLoop1" GROUP="RocketLauncher"

var vector OldVel;
var bool bSmoking;
var float SpeedModifier;
var vector InitialDir;
var bool bHitWater, bBubbling;
var byte Sequence;
var float SmokeRate;
// #if GAMEVER==227
var FSFXRLSmokeTrail MyTrailer;
// #endif

replication
{
	reliable if ( Role == ROLE_Authority && bNetInitial )
		Sequence, SpeedModifier, OldVel, bSmoking, bBubbling;
}

simulated function BeginPlay()
{
	if( Level.NetMode!=NM_DedicatedServer )
	{
		PlaySound(SpawnSound,SLOT_None);
// #if GAMEVER==227
		if( MyTrailer==None && !Region.Zone.bWaterZone )
			MyTrailer = Spawn(Class'FSFXRLSmokeTrail',Self);
// #endif
	}	
}

function PostBeginPlay()
{
	if( Level.Game.IsA( 'DeathMatchGame' ) )
		Damage -= 95; //35
	Super.PostBeginPlay();
}
simulated function Destroyed()
{
// #if GAMEVER==227
	if( MyTrailer!=None )
	{
		MyTrailer.Kill();
		MyTrailer.LifeSpan = 2;
		MyTrailer = None;
	}
// #endif
}
simulated function Tick(float DeltaTime)
{
	local Effects e;

	Velocity *= (1.f+(DeltaTime*10.f));

	if( Level.NetMode==NM_DedicatedServer )
		return;
	if( AnimSequence!='Fly' && VSize( Velocity ) > 1200 && bSmoking )
		LoopAnim( 'Fly' );
// #if GAMEVER!=227
	// if ( bSmoking && SmokeRate<Level.TimeSeconds )
	// {
		// e = Spawn( class'RisingSpriteSmokePuff',,, Location );
		// e.RemoteRole = ROLE_None;
		// e.DrawScale += 0.75 + FRand();
		// SmokeRate = Level.TimeSeconds+0.06f;
	// }
	// else
// #endif
	if( bBubbling && SmokeRate<Level.TimeSeconds )
	{
		if( AnimSequence!='Wings' )
			LoopAnim( 'Wings' );
		RotationRate.Roll = 90000;
		e = Spawn( class'Bubble', Instigator,,Location );
		e.RemoteRole = ROLE_None;
		e.ScaleGlow = 0.5;
		SmokeRate = Level.TimeSeconds+0.08f;
	}
}

simulated function Explode( vector HitLocation, vector HitNormal )
{
// #if GAMEVER==227
	if( Level.NetMode != NM_DedicatedServer )
		Spawn( class'FSFXRLExplosion',,, HitLocation + HitNormal * 16 );
// #else
	// local Effects E;
// 
	// if( Level.NetMode != NM_DedicatedServer )
	// {
		// E = spawn( class'FsBurst',,, HitLocation + HitNormal * 16 );
		// E.RemoteRole = ROLE_None;
		// E = spawn( class'ParticleBurst3',,, HitLocation + HitNormal * 16 );
		// E.DrawScale = 1.5;
		// E.RemoteRole = ROLE_None;
		// E = Spawn(Class 'EBRingExplosion',,,HitLocation + HitNormal*8, rotator(HitNormal));
		// E.DrawScale = 0.75;
		// E.RemoteRole = ROLE_None;
		// E = Spawn(class'FsExplosion1',,, HitLocation + HitNormal * 8 , rotator( HitNormal ));
		// E.RemoteRole = ROLE_None;
	// }
// #endif
	BlowUp(HitLocation);
	Destroy();
}
function BlowUp(vector HitLocation)
{
	HurtRadius(Damage,340.0, 'exploded', MomentumTransfer, HitLocation );
	MakeNoise(1.0);
}

// ================================================================================================
// Flying State
// ================================================================================================

auto state Flying
{
	simulated function ProcessTouch( Actor Other, Vector HitLocation )
	{
		if ( ( Other != instigator) && ( FSRocket( Other ) == none ) )
	 		Explode( HitLocation, Normal( HitLocation - Other.Location ) );
	}

	function BeginState()
	{
		initialDir = vector( Rotation );
		Velocity = speed * initialDir;
		Acceleration = initialDir * 50;
		Sequence = 1;
		PlayAnim( 'Popup', 0.001 );
		RotationRate.Roll = 75000;
		if ( Region.Zone.bWaterZone )
		{
			bHitWater = True;
			bSmoking = False;
			bBubbling = True;
			Velocity = 0.6 * Velocity;
		}
	}

	simulated function ZoneChange( Zoneinfo NewZone )
	{
		if ( !NewZone.bWaterZone || bHitWater )
		{
			if ( bBubbling )
			{
				bBubbling = False;
				bSmoking = True;
				PlayAnim( 'Wings', 0.15 );
			}
			return;
		}
// #if GAMEVER==227
		else if( NewZone.bWaterZone && MyTrailer!=None )
		{
			MyTrailer.Kill();
			MyTrailer.LifeSpan = 2;
			MyTrailer = None;
		}
// #endif
		bSmoking = False;
		bHitWater = True;
		bBubbling = True;
		RotationRate.Pitch = 0;
		RotationRate.Roll = 90000 * 2 * 0.5 - 10000;
		Velocity = 0.6 * Velocity;
	}

	simulated function AnimEnd()
	{
		if( Sequence == 1 )
		{
			Oldvel = Velocity;
			Velocity *= 0.37;
			PlayAnim( 'Wings', 0.001 );
			RotationRate.Roll = 80000;
		}
		else if( Sequence == 2 )
		{
			bSmoking = True;
			Velocity = OldVel;
		}
		Sequence++;
	}
}

defaultproperties
{
    SpawnSound=Sound'RocketShot1'
    speed=850.00
    MaxSpeed=2500.00
    Damage=140 // 80.00 in conjunction with dm reduction postbeginplay
    MomentumTransfer=8500
    RemoteRole=ROLE_SimulatedProxy
    LifeSpan=10.00
    AnimSequence=Armed
    Mesh=LodMesh'rocketL'
    AmbientGlow=96
    bUnlit=True
    SoundRadius=128
    SoundVolume=255
    CollisionRadius=8.50
    CollisionHeight=2.00
    bProjTarget=True
    bBounce=True
    bFixedRotationDir=True
    RotationRate=(Pitch=0, Yaw=0, Roll=95000)
	SpeedModifier=1
}